#
#
#Sample .ascrcuser File
#
#Sample .ascrcuser file (as of 981113)
#
#
#
# User Defined Environment Variables, these can be set by user
#
# Comment out this line to prevent the user from clobbering an existing file
unset noclobber
# The temporary working area for the ASCDS applications
setenv ASCDS_TMP /tmp
setenv ASCDS_TMP_PATH $ASCDS_TMP
# The work area for all of the user data files (default = current directory)
setenv ASCDS_WORK .
# The default User Parameter File Directory is currently a relative path,
# the ./param directory. If you want to set it to a fixed directory,
# you can set it here, for example:
#
# setenv ASCDS_USER_PARAM $HOME/ascds_param
#
setenv ASCDS_USER_PARAM $ASCDS_WORK/param
# The path to the user's profile data files
setenv ASCDS_USER_PROFILE $ASCDS_WORK/profile
# The HTML browser to be used as the ASCDS Help browser
###setenv ASCDS_HELP_BROWSER Mosaic
setenv ASCDS_HELP_BROWSER netscape
# Set up alias to bring up ASCDS Help page
alias ascds_netscape "netscape -ncols 100 http://hea-www.harvard.edu/~ascds/DS_Web/DS/ascds_software_help.html &"
##############################################################################
# #
# The following options are for "special" accounts (like operations). The #
# average user will be assigned the "default" values and will not need to #
# modify anything from here down. If you are ASCDS savvy you can overide #
# the defaults between the "OVERRIDE DEFAULTS HERE" lines. #
# #
##############################################################################
#
# Set ASCDS software installation root directory(ies) - ASCDS_INSTALL
#
# Set the default installation root directory based upon the username
# First unalias whoami, save the alias and restore it afterwards
set xalias = `alias whoami`
unalias whoami
set proc_name = `whoami`
switch ($proc_name)
# Integration
case integ
case arcint
ascds_set_install_integ
breaksw
# Test
case ascdstst
case arctest
case arcbeta
ascds_set_install_test
breaksw
case arcxtest
ascds_set_install_test
breaksw
# This is set to release23 because test23 doesn't exist
# It must be changed when test23 exists
case arcoctst
case arcmptest
ascds_set_install_release23
breaksw
# Operations
case ascdsops
case arcops
case arcsao
ascds_set_install_ops
breaksw
case arcxops
case arcxrcf
ascds_set_install_release
breaksw
case arcoc
ascds_set_install_release23
breaksw
# Others
default
# Users may select one of the three options below as a default.
# The line below (ascds_set_install_release) should be uncommented to point
# to Release 4
ascds_set_install_release
# The line below (ascds_set_install_daily) should be uncommented to point to
# the daily build for all releases; use with caution - this area changes daily
# ascds_set_install_daily
# The line below (ascds_set_install_release23) should be uncommented to point
# to Release 23 (Mission Planning and Proposal Applications)
# ascds_set_install_release23
breaksw
endsw
######################### OVERRIDE DEFAULTS HERE #########################
######################### vvvvvvvvvvvvvvvvvvvvvv #########################
#
# 1) Set user-defined developer & group installation locations (for developers)
# [default for Clearcase is /vobs/ASC_BUILD]
set ascds_developer_dir = "/vobs/ASC_BUILD" #*** Put your workspace here ***
set ascds_grp_dir = "/vobs/ASC_BUILD" #*** Put your group workspace here***
# Aliases are defined here; no changes required
alias ascds_set_install_developer "setenv ASCDS_INSTALL $ascds_developer_dir"
alias ascds_add_install_developer \
'setenv ASCDS_INSTALL "$ASCDS_INSTALL $ascds_developer_dir"'
alias ascds_set_install_grp "setenv ASCDS_INSTALL $ascds_grp_dir"
alias ascds_add_install_grp \
'setenv ASCDS_INSTALL "$ASCDS_INSTALL $ascds_grp_dir"'
# 2) Define your preferences here. The first choice must be of the "set" type,
# while the subsequent paths must be of the "add" type.
# Working versions of developers and group software
# ascds_set_install_developer
## ascds_set_install_grp
# ascds_add_install_grp
# Daily build of Mission Planning and Proposal Applications
## ascds_set_install_daily23
# ascds_add_install_daily23
# Release of Mission Planning Applications
## ascds_add_install_release2
# Release of Proposal Applications (not available)
## ascds_add_install_release3
######################### ^^^^^^^^^^^^^^^^^^^^^^ #########################
######################### OVERRIDE DEFAULTS HERE #########################
#
# Add bin directories to Search Path from each directory in $ASCDS_INSTALL
#
# Note: command line arguments to .ascrc override values set in .ascrcuser
if ( "$ascds_rel_str" != "" ) then
setenv ASCDS_INSTALL $ascds_rel_str
endif
foreach _dir ( $ASCDS_INSTALL )
ascds_addpath $_dir/bin
end
#
# Source the setup script (Note: case statements moved to ascds_setup_all)
#
ascds_source ascds_setup_all
######################### OVERRIDE DEFAULTS HERE #########################
######################### vvvvvvvvvvvvvvvvvvvvvv #########################
# The above default "ascds_source ascds_setup_all" runs setup scripts for all
# the ASCDS software except Automatic Pipeline Processing. Automatic
# processing is setup with ascds_setup_ap. If you want to change the default
# (add automatic processing or skip other setups) you can override by
# commenting out the above default and resetting it here,
# for example:
#
# ### ascds_source ascds_setup_all # comment this out
# ascds_source ascds_setup_general
# ascds_source ascds_setup_scidev
# or
# ascds_source ascds_setup_ap sdp
# Or you can override the defaults by adding the following .ascrcuser.override
# file in your home directory.
if ( -r ${HOME}/.ascrcuser.override ) source ${HOME}/.ascrcuser.override
######################### ^^^^^^^^^^^^^^^^^^^^^^ #########################
######################### OVERRIDE DEFAULTS HERE #########################
#reset whoami if user had previously aliased it to something else
if ("$xalias" != "") then
alias whoami ' $xalias '
endif
#
# Show the user what version of the software is being run
#
ascds_version
#
#
#