PRO eae_list, eae_rdb, file_out, FRAC_LINK=frac_link
; Make a nice listing of the eae_rdf file's data...
;
; 11/19/97 dd Change to photons instead of counts
;  3/09/98 dd Add html links to feature-fraction plots
;

ff_web_dir = 'FF_GIFS/'

; Open an output file
if n_elements(file_out) EQ 0 then file_out = 'eae_list.txt'
OPENW, out_unit, file_out, /GET_LUN

if KEYWORD_SET(FRAC_LINK) then begin
  printf, out_unit, '<PRE>'
  TAB = STRING(9B)
  printf, out_unit, TAB+TAB+TAB+TAB+TAB+TAB+TAB+ $
	'<B><A href="line_frac.html#plots">Description of MARX plots</A></B>'
end

; print the header
header = 'index    TRW-ID       Energy Source,Filter  Shutters  Grat. Order' +$
	' Det.  Apert. date run_id iter    Flux/meth     [BND ap.s]  '+ $
	'  FP ph/s   Eff.Area  Effic.  Fractions    Reference_id'

for ir=0,n_elements(eae_rdb)-1 do begin
  if FIX(20.*FLOAT((ir)/20)) EQ (ir) then begin
    print, ''
    print, header
    printf, out_unit, ''
    printf, out_unit, header
  end
  line_out = STRPAD(STRING(ir),/COMP,5)
  line_out = line_out + STRPAD(eae_rdb(ir).trw_id,17)
  line_out = line_out + STRPAD(STRING(eae_rdb(ir).energy),7,/CLIP,/COMP)+'  '
  line_out = line_out + STRPAD(eae_rdb(ir).source,13)
  line_out = line_out + STRPAD(eae_rdb(ir).shutters,11)
  line_out = line_out + STRPAD(eae_rdb(ir).grating,5)
  line_out = line_out + STRPAD(STRING(FIX(eae_rdb(ir).order)), $
		4,/COMP,/RIGHT)+'  '
  line_out = line_out + STRPAD(eae_rdb(ir).fp_detector,6,/CLIP)
  if KEYWORD_SET(FRAC_LINK) then begin
    if TOTAL(ir EQ frac_link) GT 0 then begin
      ap_w_link = STRPAD(STRING(LONG(eae_rdb(ir).fp_aperture)), $
		5, /CLIP,/COMP, /RIGHT) + '  '
      ap_w_link = '<B><A href="'+ ff_web_dir + eae_rdb(ir).trw_id + $
		'_i' + eae_rdb(ir).iteration + '_ff.gif' + $
		'">'+ap_w_link+'</A></B>'
      line_out = line_out + ap_w_link
    end else begin
    line_out = line_out + STRPAD(STRING(LONG(eae_rdb(ir).fp_aperture)), $
		5, /CLIP,/COMP, /RIGHT) + '  '
    end
  end else begin
    line_out = line_out + STRPAD(STRING(LONG(eae_rdb(ir).fp_aperture)), $
		5, /CLIP,/COMP, /RIGHT) + '  '
  end
  line_out = line_out + STRPAD(eae_rdb(ir).mst_date,7)
  line_out = line_out + STRPAD( eae_rdb(ir).run_id, $
				6,/COMP,/RIGHT ) + $
			'i' + STRPAD(eae_rdb(ir).iteration, 5, /COMP, /CLIP)
  line_out = line_out + STRPAD(STRING(eae_rdb(ir).flux),5,/COMP,/RIGHT,/CLIP)
  line_out = line_out + ' '+STRPAD(eae_rdb(ir).flux_method,6,/CLIP)+'  '
  line_out = line_out + STRPAD('['+eae_rdb(ir).fpc_hn_aperture,5)
  line_out = line_out + STRPAD(eae_rdb(ir).fpc_5_aperture,4)
  line_out = line_out + STRPAD(eae_rdb(ir).ssd_5_aperture,3)+'] '
  line_out = line_out + STRPAD(STRING(eae_rdb(ir).focal_line,FORMAT='(F9.3)'),9,/COMP,/RIGHT)
  line_out = line_out + STRPAD(STRING(eae_rdb(ir).effective,FORMAT='(F8.3)'),9,/COMP,/RIGHT)
  line_out = line_out + STRPAD(STRING(eae_rdb(ir).effic,FORMAT='(F8.4)'),9,/COMP,/RIGHT)
  ; give the correction fractions if available...
  meth_str = eae_rdb(ir).effic_method
  if STRPOS(meth_str,'frac') GE 0 then begin
    ; fraction corrected...
    comma = STRPOS(meth_str,',')
    lparen = STRPOS(meth_str,'(')
    frac_str = ' '+STRMID(meth_str, comma+2, (lparen-comma)-3)
  end else begin
    if eae_rdb(ir).effic GT 0. then begin
      frac_str = '  (simple)  '
    end else frac_str = '            '
  end
  line_out = line_out + frac_str
  line_out = line_out + '  '+eae_rdb(ir).reference_id
  print, line_out
  printf, out_unit, line_out
end

if KEYWORD_SET(FRAC_LINK) then begin
  printf, out_unit, '</PRE>'
end
CLOSE, out_unit
FREE_LUN, out_unit

RETURN
END